Pregunta En error junto con el cuadro de mensaje en VBA


En uno de mis códigos, si recibo un error, necesito que aparezca el nombre del archivo con el error y luego reanudar el proceso. A continuación se muestra el fragmento de código que estoy tratando de usar, pero me está dando un error. Alguien puede ayudarme

sourcefilename = File_list.Cells(i + 1, 1)
    Set Baccha_Wbk = Wbk.Workbooks.Open(sourcefilename)
    On Error GoTo ErrMsg
ErrMsg:    MsgBox ("Error in file" & sourcefilename ),On Error Resume Next

5
2017-09-09 08:17


origen


Respuestas:


Otra forma de hacerlo ...

Sub Sample()
    Dim sFile As String
    '~~> If you are doing this in Excel. then you don't need Wbk
    Dim Wbk As Excel.Application
    Dim Baccha_Wbk As Workbook
    Dim i As Long

    On Error GoTo Whoa

    '
    '~~> Rest of the Code
    '

    sFile = File_list.Cells(i + 1, 1)

    If FileFolderExists(sFile) Then
        '~~> If you are doing this in Excel. then you don't need Wbk
        Set Baccha_Wbk = Wbk.Workbooks.Open(sFile)
    Else
        MsgBox "File Doesn't exists"
    End If

    Exit Sub
Whoa:
    MsgBox Err.Description
End Sub

Public Function FileFolderExists(strFullPath As String) As Boolean
    On Error GoTo EarlyExit
    If Not Dir(strFullPath, vbDirectory) = vbNullString Then FileFolderExists = True
EarlyExit:
    On Error GoTo 0
End Function

5
2017-09-09 08:37



Ya casi estás ahí. Así es como puedes hacerlo:

sourcefilename = File_list.Cells(i + 1, 1)
On Error Resume Next 'Errors get swallowed without warning. Use sparingly.
Set Baccha_Wbk = Wbk.Workbooks.Open(sourcefilename)
If Err.Number <> 0 Then MsgBox ("Error in file" & sourcefilename )
On Error Goto 0 'Back to normal: errors get thrown as usual

Un controlador de error más completo podría verse así:

Sub abcd()
    On Error GoTo ErrorHandler

    '[code...]

    sourcefilename = File_list.Cells(i + 1, 1)
    Set Baccha_Wbk = Wbk.Workbooks.Open(sourcefilename)

    '[more code...]

ExitProcedure:
    On Error Resume Next
    'Clean-up code goes here
    Exit Sub

ErrorHandler:
    Select Case Err.Number
    'Deal with each of the expected errors
    Case 53 ' File not found
        MsgBox "File not found: " & sourcefilename
    Case 70 ' Permission denied
        MsgBox "Permission denied. Maybe you don't have permission to access this drive? " & sourcefilename
    'etc. etc.

    'Deal with unexpected errors
    Case Else
        UnexpectedError Err.Number, Err.Source & ", Procedure abcd of Module Module1", Err.Description, Err.HelpFile, Err.HelpContext
    End Select
    Resume ExitProcedure
    Resume
End Sub

(Por qué el doble Resume ¿al final?)

junto con esta ayuda sub-personaliza como quieras.

Public Sub UnexpectedError(ByVal lngNumber As Long, _
                           ByVal strSource As String, ByVal strDescription As String, _
                           ByVal strHelpfile As String, ByVal lngHelpContext As Long)
    On Error Resume Next
    MsgBox "[" & strSource & "]" & vbCrLf & "Run-time error '" _
         & CStr(lngNumber) & "':" _
         & vbCrLf & vbCrLf & strDescription, vbExclamation, Application.Name, _
           strHelpfile, lngHelpContext
    Application.EnableEvents = True
    Debug.Print "Case " & CStr(lngNumber) & " '" & strDescription
    'Debug.Assert False 'uncomment while developing
End Sub

2
2017-09-09 08:22