Pregunta Usar Excel VBA para ejecutar una consulta SQL


Soy bastante nuevo en SQL y VBA. He escrito una consulta SQL que me gustaría poder llamar y ejecutar desde un sub de VBA en un libro de Excel y luego llevar los resultados de la consulta al libro de trabajo. He encontrado algunos subs en línea (stackoverflow y otros lugares) que pretenden hacer esto, pero estoy teniendo problemas para entenderlos, ya que no contienen ninguna explicación. Por ejemplo, aquí hay un subtítulo que encontré en línea:

Sub ConnectSqlServer()

    Dim conn As ADODB.Connection
    Dim rs As ADODB.Recordset
    Dim sConnString As String

    ' Create the connection string.
    sConnString = "Provider=SQLOLEDB;Data Source=INSTANCE\SQLEXPRESS;" & _
                  "Initial Catalog=MyDatabaseName;" & _
                  "Integrated Security=SSPI;"

    ' Create the Connection and Recordset objects.
    Set conn = New ADODB.Connection
    Set rs = New ADODB.Recordset

    ' Open the connection and execute.
    conn.Open sConnString
    Set rs = conn.Execute("SELECT * FROM Table1;")

    ' Check we have data.
    If Not rs.EOF Then
        ' Transfer result.
        Sheets(1).Range("A1").CopyFromRecordset rs
    ' Close the recordset
        rs.Close
    Else
        MsgBox "Error: No records returned.", vbCritical
    End If

    ' Clean up
    If CBool(conn.State And adStateOpen) Then conn.Close
    Set conn = Nothing
    Set rs = Nothing

End Sub

Antes que nada, ¿funcionaría esto? En segundo lugar, ¿qué necesito reemplazar en el submarino (parece proveedor, fuente de datos, catálogo inicial, etc.) y dónde encuentro la información para reemplazarlos?

¡Espero que esta pregunta no sea demasiado confusa y agradezco tu ayuda!


32
2017-12-09 17:37


origen


Respuestas:


A continuación se muestra el código que utilizo actualmente para extraer datos de un MS SQL Server 2008 a VBA. Debe asegurarse de tener la referencia ADODB adecuada [Editor VBA-> Herramientas-> Referencias] y asegúrate de tener Biblioteca Microsoft ActiveX Data Objects 2.8 marcado, que es el segundo de la fila inferior que está marcada (estoy usando Excel 2010 en Windows 7, es posible que tenga una versión de ActiveX ligeramente diferente, pero todavía comenzará con Microsoft ActiveX):

References required for SQL

Submódulo para conectar a MS SQL con host remoto y nombre de usuario / contraseña

Sub Download_Standard_BOM()
'Initializes variables
Dim cnn As New ADODB.Connection
Dim rst As New ADODB.Recordset
Dim ConnectionString As String
Dim StrQuery As String

'Setup the connection string for accessing MS SQL database
   'Make sure to change:
       '1: PASSWORD
       '2: USERNAME
       '3: REMOTE_IP_ADDRESS
       '4: DATABASE
    ConnectionString = "Provider=SQLOLEDB.1;Password=PASSWORD;Persist Security Info=True;User ID=USERNAME;Data Source=REMOTE_IP_ADDRESS;Use Procedure for Prepare=1;Auto Translate=True;Packet Size=4096;Use Encryption for Data=False;Tag with column collation when possible=False;Initial Catalog=DATABASE"

    'Opens connection to the database
    cnn.Open ConnectionString
    'Timeout error in seconds for executing the entire query; this will run for 15 minutes before VBA timesout, but your database might timeout before this value
    cnn.CommandTimeout = 900

    'This is your actual MS SQL query that you need to run; you should check this query first using a more robust SQL editor (such as HeidiSQL) to ensure your query is valid
    StrQuery = "SELECT TOP 10 * FROM tbl_table"

    'Performs the actual query
    rst.Open StrQuery, cnn
    'Dumps all the results from the StrQuery into cell A2 of the first sheet in the active workbook
    Sheets(1).Range("A2").CopyFromRecordset rst
End Sub

36
2017-12-09 18:25